EROARE CONECTARE

[claudiap]

Buna seara,

Dupa actualizare nu ma mai pot conecta la Saga. Primesc urmatoarea eroare:

Eroare conectare
---------------------------
Programul nu s-a putut conecta la baza de date. DBNAME=127.0.0.1/3060:C:\SAGA C.3.0\config.fdb;CHARSET=WIN1252;Client=C:\SAGA C.3.0\FbClient\fbclient.dll; Connectivity error: [ODBC Firebird Driver]file C:\SAGA C.3.0\CONFIG.FDB is not a valid database
IProvider::attachDatabase failed when loading mapping cache [ODBC Firebird Driver]file C:\SAGA C.3.0\CONFIG.FDB is not a valid database
IProvider::attachDatabase failed when loading mapping cache

Multumesc,

[ciucam544]

Se pare ca fisierul config.fdb este corupt (parti din fisier au fost alterate). Exista sau nu o soluite simpla in functie de context.
Stergeti config.fdb si redeschideti saga de 2 ori. Reconfigurati setarile (utilizatori si parole daca existau).
Ori restaurati un config.fdb din cel mai recent backup de folder saga (nu salvarile bazelor).

[herganiec]

Ori restaurati un config.fdb din cel mai recent backup de folder saga (nu salvarile bazelor).

nu știu dacă utilizatorii copiază TOT folderul Saga vreodată (durează f mult și e foarte voluminos dacă ai firme mai multe pt că în el sunt și SALV_BD ce ocupă enorm).... , cei mai mulți fac doar salvarea baze de date a firmelor pe stick.

[balazse246]

Acel folder se poate curata, mai exact, din folderul "actualizari" se pot sterge fisierele cu actualizarile in urma actualizarilor automate, precum si din salv_bd se pot sterge fisierele sa ramana doar ultimele 15 salvari (asta daca faci copie de siguranta la fiecare versiune).
Poti sa ail o marime acceptabila daca intretii folderul.
De altfel, in fiecare e-mail este mentionat clar, ca pentru a prevenii problemele, cel mai bine este sa faci o copie de siguranta a folderului "SAGA C.3.0", si nu zice sa faci doar salvari.

[nicolam76]

zice , zice.. nu e practic, e greoi si durează să îl salvezi tot cand e 120-150 gb. nici nu ai pe ce.. cei mai multi folosesc stick-uri ..

[balazse246]

La 120 GB deja ai cateva sute bune de firme (si nu stiu daca ii curatat), si atunci deja poate merita sa te gandesti sa imparti in mai multe sesiuni programul, adica firme fara activitate, cu activitate redusa si normal.
Acest tip de cazuri le gasesti doar la firme de contabilitate.
Dar asta ii deja parerea mea personala.

[ciucam544]

ScriptBackup_FolderSAGA_Compact.cmd

Cod: Selectaţi tot

@echo off
setlocal enabledelayedexpansion
set "CPATH=%~dp0"
set "CPATH=%CPATH:~0,-1%"
net session >nul 2>&1 || (setx SagaCale "%CPATH%" >nul & powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs" & exit /b)
title -Backup Folder Saga Compact- 2026(c)byGabrieL
for /f "delims=" %%C in ('powershell -NoProfile -Command "(Get-Item Env:SagaCale).Value"') do set "CaleSaga=%%C"
if not defined CaleSaga set "CaleSaga=%CPATH%"
if exist "%CaleSaga%\sb.exe" set "SagaTip=SagaB"
if exist "%CaleSaga%\sc.exe" set "SagaTip=SagaC"
if exist "%CaleSaga%\sps.exe" set "SagaTip=SagaPS"
if "%SagaTip%"=="" (color 0c & echo Nu exista un program saga in folderul curent ! & pause & exit /b)
set "DRIVE=%CaleSaga:~0,2%"
set "DEST=%DRIVE%\Backups_Saga"
for %%G in ("%CaleSaga%") do set "FName=%%~nxG"
set "FBS=FirebirdServerFirebird30_Saga"
if not exist "%DEST%" mkdir "%DEST%"
set "Z7=C:\Program Files\7-Zip\7z.exe"
set "Z7A=%CaleSaga%\7za.exe"
set "ArchEXE=" & set "Arhivator="
if exist "%Z7%" set "ArchEXE=%Z7%" & set "Arhivator=7zip"
if not defined ArchEXE if exist "%Z7A%" set "ArchEXE=%Z7A%" & set "Arhivator=7za_Saga"
if not defined ArchEXE echo Lipseste arhivatorul pentru backup! & pause & exit /b
echo Folosesc arhivator: %Arhivator%
tskill sc /a >nul 2>&1 & tskill sps /a >nul 2>&1 & sc stop %FBS% >nul 2>&1
for %%S in ("%CaleSaga%") do (
for /f %%i in ('powershell -command "Get-Date -Format \"yyyy-MM-dd_HHmmss\""') do set "DATE=%%i"
del "%%~S\*.rbk" >nul 2>&1
reg export HKCU\SOFTWARE\SAGA "%%~S\sagaset_!DATE!.rbk" /y >nul 2>&1
echo Se face Backup in %DEST%\Bkp!SagaTip!_!FName!_!DATE!.zip
"%ArchEXE%" a -tzip -mx3 "%DEST%\Bkp!SagaTip!_!FName!_!DATE!.zip" "%%~S\*" -x^^!"%%~S\Actualizari" -x^^!"%%~S\salv_bd"
)
sc start %FBS% >nul 2>&1
echo Backup SAGA finalizat cu succes!
endlocal & pause

Salvati si rulati scriptul din orice folder saga.
Face un backup compact, fara actualizari si fara salv_bd, la toate fisierele si subfolderele din acea instalare saga, pe aceeasi partitie, intr-un folder Backups_Saga.
Merge mult mai repede daca exista in windows 7z instalat. Atentie, in timpul backup-ului, serviciul firebird saga este oprit pt. a putea arhiva toate bazele.

[herganiec]

am facut fisierul .cmd și l-am pus in D:\SAGA C.3.0
il lansez si zice ca ”Nu exista un program Saga in folderul curent.”

[nicolaescu112]

Scriptul functioneaza perfect. L-am testat si totul a fost in regula. Eu am programul Saga instalat pe partitia C. Sa nu fie o problema daca este instalat pe alta partitie.

[ciucam544]

Eroarea:"Nu exista un program Saga in folderul curent." apare ca scriptul nu detecteaza sb.exe, sc.exe sau sps.exe in folderul de unde este pornit. Ori programul saga are alta denuire, ori nu a reusit sa ruleze ca admin sau scriptul este blocat din alte motive. In situatii normale nu ar trebuii sa aiba probleme. La fel, in teorie, ar trebui sa functioneze din orice folder normal (adica nu de sistem) din orice partitie.

[herganiec]

https://imgbox.com/m7PkeZn2
vezi imaginea.. cu SAGA C.3.0.. fisierul .cmd.. care are scriptul tau.. și care il lansez.. dupa care apare mesajul care l-am scris mai sus.
Da toate le țin în partiția D nu în C.
poate de asta nu funcționează.

[ciucam544]

pt. dn.ul Herganie ... Considerati sa nu mai folositi Windows 7. Totusi are aproape 17 de ani de cand a aparut si de 5 ani e ingropat. Oricum am revizuit si pt. dvs. scriptul:

ScriptBackup_FolderSAGA_Win7.cmd

Cod: Selectaţi tot

@echo off
setlocal enabledelayedexpansion
set "CPATH=%~dp0"
set "CPATH=%CPATH:~0,-1%"
net session >nul 2>&1 || (powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs -ArgumentList '\"%CPATH%\"'"; exit /b)
if "%~1"=="" (set "CaleSaga=%CPATH%") else (set "CaleSaga=%~1")
title - Backup Folder Saga Compact Win7 - 2026(c)byGabrieL
set "SagaTip="
if exist "%CaleSaga%\sb.exe"  set "SagaTip=SagaB"
if exist "%CaleSaga%\sc.exe"  set "SagaTip=SagaC"
if exist "%CaleSaga%\sps.exe" set "SagaTip=SagaPS"
if "%SagaTip%"=="" (color 0c & echo Nu exista un program Saga in folderul curent: "%CaleSaga%" & pause & exit /b)
set "DRIVE=%CaleSaga:~0,2%"
set "DEST=%DRIVE%\Backups_Saga"
for %%G in ("%CaleSaga%") do set "FName=%%~nxG"
if not exist "%DEST%" mkdir "%DEST%"
set "Z7=C:\Program Files\7-Zip\7z.exe"
set "Z7A=%CaleSaga%\7za.exe"
set "ArchEXE=" & set "Arhivator="
if exist "%Z7%"  (set "ArchEXE=%Z7%"  & set "Arhivator=7zip")
if not defined ArchEXE if exist "%Z7A%" (set "ArchEXE=%Z7A%" & set "Arhivator=7za_Saga")
if not defined ArchEXE (echo Lipseste arhivatorul pentru backup! & pause & exit /b)
echo Folosesc arhivator: %Arhivator%
taskkill /IM sc.exe /F >nul 2>&1
taskkill /IM sps.exe /F >nul 2>&1
"%SystemRoot%\System32\sc.exe" stop FirebirdServerFirebird30_Saga >nul 2>&1
for /f %%i in ('powershell -command "Get-Date -Format \"yyyy-MM-dd_HHmmss\""') do set "DATE=%%i"
del "%CaleSaga%\*.rbk" >nul 2>&1
reg export HKCU\SOFTWARE\SAGA "%CaleSaga%\sagaset_!DATE!.rbk" /y >nul 2>&1
echo Se face Backup in %DEST%\Bkp!SagaTip!_!FName!_!DATE!.zip
"%ArchEXE%" a -tzip -mx3 "%DEST%\Bkp!SagaTip!_!FName!_!DATE!.zip" "%CaleSaga%\*" -x^^!"%CaleSaga%\Actualizari" -x^^!"%CaleSaga%\salv_bd"
"%SystemRoot%\System32\sc.exe" start FirebirdServerFirebird30_Saga >nul 2>&1
echo.
echo Backup SAGA finalizat cu succes!
endlocal & pause

[herganiec]

E win11 64biti.

[herganiec]

acesta a functionat fara probleme..

[ciucam544]

E win11 64biti.

Ca sa zic, greseala mea. Am obosit sa mai ghicesc ce are fiecare in calculator. Alta e neconcordanta la dvs. dar nu mai intru in detalii. Bine ca merege varianta a 2a de script.